home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
EnigmA Amiga Run 1996 February
/
EnigmA AMIGA RUN 04 (1996)(G.R. Edizioni)(IT)[!][issue 1996-02][Skylink CD III].iso
/
earcd
/
comm2
/
zpont311.lha
/
zpoint-3.11
/
Rexx
/
ReplyMessage.cedzp
< prev
next >
Wrap
Text File
|
1995-03-09
|
3KB
|
109 lines
/*
ReplyMessage.cedzp 0.9 (26.2.94) by Ueli Kaufmann
ARexx Skript für Zodiac's Point V37.115ß und Cygnus-Ed v2.12
Zweck:
------
Die aktuelle Nachricht vom Cygnus-Editor aus kommentieren.
Harmoniert hervorragend mit ReadMessageExternal.cedzp ...
Vorgehensweise:
---------------
Wenn mittels ReadMessageExternal.cedzp Nachrichten gelesen werden,
so kann mit ReplyMessage.cedzp eine Reply auf auf die aktuelle
Nachricht erstellt werden.
Wenn das Reply erstellt worden ist, wird mit einem erneuten Starten
von ReplyMessage.cedzp das Reply abgeschickt..
Zukuenftiges:
-------------
- EBs, Cookies und Quote-Initialen sollten noch beachtet werden..
*/
txtFile = 'T:ReplyMsg.tmp'
parse arg zpPort /* ZP-Portname als Argument erhalten. */
if zpPort == "" then /* Wirklich? */
zpPort = "ZPoint" /* Nein, Standard-Portname annehmen. */
options results /* Resultate zulassen. */
address "rexx_ced"
STATUS 19 /* Pfadname samt Filename ermitteln */
if RESULT == txtFile then /* ReplyFile schon erstellt? */
do /* Ja, Reply verschicken. */
'Save & quit' /* Reply speichern und Fenster schliessen. */
address value zpPort /* Kanal zu ZP oeffnen. */
MESSAGEINFO Author /* Adresse der aktuellen Nachricht ermitteln */
msgAuthor = RESULT
msgAuthor = 'RECEIVER "'msgAuthor'"'
MESSAGEINFO ID /* Nachrichten-ID der aktuellen Nachricht ermitteln */
msgID = RESULT
msgID = 'REFERENCE' msgID
MESSAGEINFO Subject /* Nachrichten-Betreff der aktuellen Nachricht ermitteln */
msgSubj = RESULT
cpos = pos("Re:",msgSubj)
if cpos = 0 then
msgSubj = "Re:" msgSubj
msgSubj = 'SUBJECT "'msgSubj'"'
WRITEMESSAGE txtFile msgAuthor msgSubj msgID
if rc == 0 then /* Erfolgreich? */
OKAY1 "Nachricht konnte nicht verschickt werden.."
end
else /* Reply-File erstellen.. */
do
address Command "Delete >nil:" txtFile /* mögliches altes File löschen */
address value zpPort /* Kanal zu ZP oeffnen. */
MESSAGEINFO Type
if RESULT = "TEXT" then
do
SAVEMESSAGEBODY txtFile /* Nachricht speichern */
if rc = 0 then
do
address "rexx_ced"
OKAY1 "ZP konnte den Nachrichtenrumpf nicht speichern."
exit
end
MESSAGEINFO Author /* Adresse der aktuellen Nachricht ermitteln */
msgAuthor = RESULT
address "rexx_ced"
'Open new' /* neues Fenster oeffnen */
if RESULT == 0 then /* hatten wir Erfolg? */
do /* Nein :-( */
OKAY1 "Es konnte kein weiteres Fenster mehr im ced geoeffnet werden.. <<"
exit /* Skript abbrechen */
end
'Open...' txtFile /* File laden */
if RESULT == 0 then /* hatten wir Erfolg? */
do /* Nein :-( */
OKAY1 "'"txtFile"' konnte vom ced nicht geladen werden.."
exit /* Skript abbrechen */
end
TEXT '0a'x msgAuthor "writes:" || '0a'x || '0a'x /* Header-Zeile schreiben */
LEFT
LEFT
lstring = '"' || '0a'x || '"' || ' ' || '"' || '0a'x || '> "'
'Replace...' lstring 1 0 1 0 't' /* "LF" durch "LF> " ersetzen */
end
end
exit